{ config, pkgs, lib, ... }:

let
  domain = "media.giugl.io";
  port = 8096;
  
  utilities = import ./utilities.nix { inherit lib config; };
  inherit (utilities) architectInterfaceAddress;
in
{
  # needed since StateDirectory does not accept symlinks
  systemd.services.jellyfin.serviceConfig.StateDirectory = lib.mkForce "";

  services = {
    jellyfin = {
      enable = true;
      group = "media";
      package = pkgs.unstablePkgs.jellyfin;
    };

    nginx.virtualHosts.${domain} = {
      forceSSL = true;
      enableACME = true;
      extraConfig = ''
        # External Javascript (such as cast_sender.js for Chromecast) must be whitelisted.
        #add_header Content-Security-Policy "default-src https: data: blob: http://image.tmdb.org; style-src 'self' 'unsafe-inline'; script-src 'self' 'unsafe-inline' https://www.gstatic.com/cv/js/sender/v1/cast_sender.js https://www.gstatic.com/eureka/clank/95/cast_sender.js https://www.gstatic.com/eureka/clank/96/cast_sender.js https://www.gstatic.com/eureka/clank/97/cast_sender.js https://www.youtube.com blob:; worker-src 'self' blob:; connect-src 'self'; object-src 'none'; frame-ancestors 'self'";
        # Disable buffering when the nginx proxy gets very resource heavy upon streaming
        proxy_buffering off;

        allow ${config.architect.networks.lan.net};
        allow ${config.architect.networks.tailscale.net};
        deny all;
      '';

      locations."/" = {
        proxyPass = "http://127.0.0.1:${toString port}";
      };

      locations."/socket" = {
        proxyPass = "http://127.0.0.1:${toString port}";
        proxyWebsockets = true;
      };
    };
  };


  networking.extraHosts = ''
    ${architectInterfaceAddress "lan"} ${domain}
    ${architectInterfaceAddress "wireguard"} ${domain}
    ${architectInterfaceAddress "tailscale"} ${domain}
  '';

  users.groups = {
    media.members = [ "jellyfin" ];
    video.members = [ "jellyfin" ];
    render.members = [ "jellyfin" ];
  };

  fileSystems."/tmp/jellyfin" = {
    device = "none";
    fsType = "tmpfs";
    options = [ "defaults" "size=20G" "uid=jellyfin" ];
  };
}