nixos/flake.nix

{
  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/release-23.11";
    nixos-unstable.url = "github:NixOS/nixpkgs/nixos-unstable";
    local-unstable.url = "path:///home/giulio/dev/nixpkgs";
    home-manager = {
      url = "github:nix-community/home-manager/release-23.11";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs = { self, nixpkgs, nixos-unstable, local-unstable, home-manager }:
    let
      sysLinuxX64 = "x86_64-linux";
      sysDarwin = "aarch64-darwin";
      sysLinuxAarch = "aarch64-linux";

      wrapPkgsSystem = { system, cudaSupport ? false }:
        let
          config = {
            inherit cudaSupport;
            allowUnfree = true;
          };
        in
        import nixpkgs rec {
          inherit system config;

          unstablePkgs = import nixos-unstable {
            inherit system config;
          };

          localPkgs = import local-unstable {
            inherit system config;
          };

          overlays = [
            (final: prev: { inherit unstablePkgs; })
            (final: prev: { inherit localPkgs; })
          ];
        };

      wrapUtils = { pkgs, system }:
        let
          inherit (pkgs.lib) makeScope;
          inherit (pkgs) newScope;
        in
        makeScope newScope (self: rec {
          inherit nixpkgs home-manager nixos-unstable;
          inherit (self.callPackage ./lib/utils.nix { }) mkSysRole mkHomeRole;
          inherit (user) mkUser;

          user = self.callPackage ./lib/user.nix { };
          host = self.callPackage ./lib/host.nix { };
        });


      pkgsLinuxX64Cuda = wrapPkgsSystem { system = sysLinuxX64; cudaSupport = true; };
      utilsLinuxX64Cuda = wrapUtils { system = sysLinuxX64; pkgs = pkgsLinuxX64Cuda; };

      pkgsLinuxAarch = wrapPkgsSystem { system = sysLinuxAarch; };
      utilsLinuxAarch = wrapUtils { system = sysLinuxAarch; pkgs = pkgsLinuxAarch; };

      pkgsDarwin = wrapPkgsSystem { system = sysDarwin; };
      utilsDarwin = wrapUtils { system = sysDarwin; pkgs = pkgsDarwin; };
    in
    {
      nixosConfigurations = {
        architect = utilsLinuxX64Cuda.host.mkHost {
          name = "architect";
          users = [{
            user = "giulio";
            roles = [ ];
          }];
        };
        gAluminum = utilsLinuxX64Cuda.host.mkHost {
          name = "gAluminum";
          users = [{
            user = "giulio";
            roles = [ "desktop" "ssh" "git" ];
          }];
          roles = [ "gnome" ];
        };
      };

      homeConfigurations = {
        giulioMac = utilsDarwin.user.mkHMUser {
          name = "giulio";
          roles = [ "ssh" ];
        };
        giulioAarch = utilsLinuxAarch.user.mkHMUser {
          name = "giulio";
          roles = [ "ssh" ];
        };
        giulioX64 = utilsLinuxX64Cuda.user.mkHMUser {
          name = "giulio";
          roles = [ "ssh" "go" ];
        };
        giulioX64NoSSH = utilsLinuxX64Cuda.user.mkHMUser {
          name = "giulio";
          roles = [ "go" ];
        };
      };

      defaultTemplate = self.templates.basicShell;
      templates = {
        basicShell = {
          path = ./templates/basicShell;
          description = "A barebone shell with custom defined packages";
        };
      };
    };
}